_inputs:
{
  config,
  lib,
  pkgs,
  ...
}:
let
  inherit (config) location;
in
{
  environment.systemPackages = [ pkgs.gnome-themes-extra ];

  home-manager.users.minijackson =
    { config, ... }:
    {
      gtk = {
        enable = true;
        gtk2.configLocation = "${config.xdg.configHome}/gtk-2.0/gtkrc";

        iconTheme = {
          # TODO: properly modify the colors
          # High priority, because gnome-themes-extra below also pulls the
          # Adwaita icon theme, which leads to a conflict
          package = lib.hiPrio (
            pkgs.tela-circle-icon-theme.override {
              colorVariants = [ "brown" ];
            }
          );
          name = "Tela-circle-brown-dark";
        };
      };

      dconf.settings = {
        "org/gnome/desktop/interface" = {
          color-scheme = "prefer-dark";
        };
      };

      services.darkman = {
        enable = true;

        settings = {
          lat = location.latitude;
          lng = location.longitude;
          usegeoclue = location.provider == "geoclue2";
        };

        darkModeScripts.gtk-theme = ''
          ${lib.getExe pkgs.dconf} write /org/gnome/desktop/interface/color-scheme "'prefer-dark'"
          ${lib.getExe pkgs.dconf} write /org/gnome/desktop/interface/gtk-theme "'Adwaita-dark'"
        '';

        lightModeScripts.gtk-theme = ''
          ${lib.getExe pkgs.dconf} write /org/gnome/desktop/interface/color-scheme "'prefer-light'"
          ${lib.getExe pkgs.dconf} write /org/gnome/desktop/interface/gtk-theme "'Adwaita'"
        '';
      };
    };
}