inputs:

{ config, pkgs, lib, ... }:

with import ../lib/theme.nix { inherit lib; };
let
  dominantEscapeCode = fgEscapeCode config.theme.colors.dominant;
  bgDominantEscapeCode = bgEscapeCode config.theme.colors.dominant;
  backgroundEscapeCode = fgEscapeCode config.theme.colors.background;
in
{
  imports = [
    (import ./commandline/dircolors.nix inputs)
    (import ./commandline/git.nix inputs)
    (import ./commandline/htop.nix inputs)
    (import ./commandline/tmux.nix inputs)
    (import ./commandline/zsh.nix inputs)
  ];

  environment.shellAliases = {
    ll = "ls -l";
    e = "\${EDITOR}";
    cpr = "${pkgs.rsync}/bin/rsync -ah --inplace --info=progress2";
  };

  programs.bash.enableCompletion = true;

  programs.less = {
    envVariables = {
      LESS = "-W -z-4 -R -J";
      LESS_TERMCAP_mb = dominantEscapeCode;
      LESS_TERMCAP_md = dominantEscapeCode;
      LESS_TERMCAP_so =
        bgDominantEscapeCode + backgroundEscapeCode + "$(tput bold)";
    };
  };

  security.sudo.extraConfig =
    let
      lectureFile = builtins.toFile "sudoers.lecture" ''
        
             ${dominantEscapeCode}"Bee" careful    __
               ${dominantEscapeCode}with sudo!    // \
                             \\_/ //
           '''-.._.-'''-.._.. -(||)(')
                             ''''

      '';
    in
    ''
      Defaults lecture = always
      Defaults lecture_file = "${lectureFile}"
    '';

  home-manager.users.minijackson = { ... }: {
    programs.bash.enable = true;

    programs.bat = {
      enable = true;
      config = {
        theme = "TwoDark";
      };
    };

    programs.pazi.enable = true;

    programs.starship = {
      enable = true;
      enableZshIntegration = false;

      settings = {
        character.symbol = ">";
        directory = {
          fish_style_pwd_dir_length = 2;
          style = "bold blue";
        };
        git_branch.symbol = "branch ";
        git_status = {
          ahead = "^";
          behind = "v";
          deleted = "x";
        };
        jobs.symbol = "+ ";
        nix_shell.style = "bold blue";
        package = {
          disabled = true;
          style = "bold green";
          symbol = "version ";
        };
        rust = {
          style = "bold dimmed yellow";
          symbol = "rust ";
        };
      };
    };
  };

  home-manager.users.root = { ... }: {
    programs.bash.enable = true;
    programs.pazi = lib.mkDefault config.home-manager.users.minijackson.programs.pazi;
    programs.bat = lib.mkDefault config.home-manager.users.minijackson.programs.bat;
  };
}