inputs: {
  config,
  pkgs,
  lib,
  ...
}:
with inputs.self.lib.theme; let
  dominantEscapeCode = fgEscapeCode config.theme.colors.dominant;
  bgDominantEscapeCode = bgEscapeCode config.theme.colors.dominant;
  backgroundEscapeCode = fgEscapeCode config.theme.colors.background;
in {
  imports = [
    (import ./commandline/dircolors.nix inputs)
    (import ./commandline/git.nix inputs)
    (import ./commandline/htop.nix inputs)
    (import ./commandline/starship.nix inputs)
    (import ./commandline/tmux.nix inputs)
    (import ./commandline/zsh.nix inputs)
  ];

  console = {
    # packages = with pkgs; [terminus_font];
    # font = "ter-d22n";
    # colors = [
    #   "282a2e"
    #   "a54242"
    #   "8c9440"
    #   "de935f"
    #   "5f819d"
    #   "85678f"
    #   "5e8d87"
    #   "707880"
    #   "373b41"
    #   "cc6666"
    #   "b5bd68"
    #   "f0c674"
    #   "81a2be"
    #   "b294bb"
    #   "8abeb7"
    #   "c5c8c6"
    # ];
    keyMap = "fr";
  };

  environment.shellAliases = {
    e = "\${EDITOR}";
    o = "xdg-open";
    cpr = "${pkgs.rsync}/bin/rsync -ah --inplace --info=progress2";
  };

  programs.bash.enableCompletion = true;

  programs.less = {
    envVariables = {
      LESS = "-W -z-4 -R -J";
      LESS_TERMCAP_mb = dominantEscapeCode;
      LESS_TERMCAP_md = dominantEscapeCode;
      LESS_TERMCAP_so =
        bgDominantEscapeCode + backgroundEscapeCode + "$(tput bold)";
    };
  };

  security.sudo.extraConfig = let
    lectureFile = builtins.toFile "sudoers.lecture" ''
      
           ${dominantEscapeCode}"Bee" careful    __
             ${dominantEscapeCode}with sudo!    // \
                           \\_/ //
         '''-.._.-'''-.._.. -(||)(')
                           ''''

    '';
  in ''
    Defaults lecture = always
    Defaults lecture_file = "${lectureFile}"

    Defaults:root,%wheel env_keep+=SSH_AUTH_SOCK
  '';

  programs.command-not-found.enable = false;
  programs.nix-index = {
    enable = true;
    enableBashIntegration = true;
    enableZshIntegration = true;
  };

  home-manager.users.minijackson = {
    programs.bash.enable = true;

    programs.bat = {
      enable = true;
      config = {
        theme = "TwoDark";
      };
    };

    programs.pazi.enable = true;

    programs.eza = {
      enable = true;
      enableAliases = true;
    };

    home.sessionVariables = {
      EXA_COLORS = let
        spec = set:
          lib.concatStringsSep ":"
          (lib.mapAttrsToList
            (key: value: "${key}=${value}")
            set);
      in
        spec {
        };
    };
  };

  home-manager.users.root = {...}: {
    programs.bash.enable = true;
    programs.pazi = lib.mkDefault config.home-manager.users.minijackson.programs.pazi;
    programs.bat = lib.mkDefault config.home-manager.users.minijackson.programs.bat;
  };
}