1 files changed, 110 insertions, 0 deletions

diff --git a/flake.nix b/flake.nix
new file mode 100644
index 0000000..4c31b37
--- /dev/null
+++ b/flake.nix
@@ -0,0 +1,110 @@
+{
+  description = "My NixOS configurations";
+
+  inputs.nixpkgs.url = "github:NixOS/nixpkgs/release-20.09";
+  inputs.nixpkgs-unstable.url = "github:NixOS/nixpkgs/master";
+  inputs.flake-utils.url = "github:numtide/flake-utils";
+  inputs.home-manager = {
+    url = "github:nix-community/home-manager/release-20.09";
+    inputs.nixpkgs.follows = "nixpkgs";
+  };
+
+  outputs = inputs @ { self, nixpkgs, nixpkgs-unstable, flake-utils, home-manager }: {
+
+    nixosModules = {
+      default = { ... }: {
+        imports = [
+          home-manager.nixosModules.home-manager
+          (import ./configuration.nix inputs)
+        ];
+      };
+
+      test = { config, ... }: {
+        imports = [ self.nixosModules.default ];
+
+        home-manager.users.minijackson.home.stateVersion = "20.09";
+        home-manager.users.root.home.stateVersion = "20.09";
+
+        users.users.minijackson.initialHashedPassword = "";
+        users.users.root.initialHashedPassword = "";
+
+        topology.mainVpn = {
+          interfaceName = "tinc.testNet";
+          subnet = "fd1f:340c:c5eb:9b18::/64";
+          currentNodeIP = "fd1f:340c:c5eb:9b18::1";
+        };
+
+        services.tinc.networks.testNet = { };
+
+        # TODO: automate that? {{{
+        networking.interfaces."tinc.testNet" = {
+          virtual = true;
+          virtualType = "tun";
+          ipv6.addresses = [{
+            address = config.topology.mainVpn.currentNodeIP;
+            prefixLength = 64;
+          }];
+        };
+
+        systemd.services."tinc.testNet" = {
+          after = [ "network-addresses-tinc.testNet.service" ];
+          requires = [ "network-addresses-tinc.testNet.service" ];
+        };
+        # }}}
+      };
+
+      usecases.common = {
+        backupClient = (import ./usecases/common/backup-client.nix inputs);
+      };
+
+      usecases.desktop = {
+        default = (import ./usecases/desktop/default.nix inputs);
+      };
+
+      usecases.server = {
+        default = (import ./usecases/server/default.nix inputs);
+        fail2ban = (import ./usecases/server/fail2ban.nix inputs);
+        monitoringTarget = (import ./usecases/server/monitoring-target.nix inputs);
+      };
+
+      profiles = {
+        desktop = (import ./profiles/desktop.nix inputs);
+        server = (import ./profiles/server.nix inputs);
+      };
+    };
+
+    nixosConfigurations = {
+      testDefault = nixpkgs.lib.nixosSystem {
+        system = "x86_64-linux";
+        modules = [
+          self.nixosModules.test
+        ];
+      };
+
+      testDesktop = nixpkgs.lib.nixosSystem {
+        system = "x86_64-linux";
+        modules = [
+          self.nixosModules.test
+          self.nixosModules.profiles.desktop
+          ({ modulesPath, ... }: {
+            imports = [ (modulesPath + "/virtualisation/qemu-vm.nix") ];
+
+            virtualisation = {
+              memorySize = 2048;
+              cores = 3;
+            };
+          })
+        ];
+      };
+
+      testServer = nixpkgs.lib.nixosSystem {
+        system = "x86_64-linux";
+        modules = [
+          self.nixosModules.test
+          self.nixosModules.profiles.server
+        ];
+      };
+    };
+
+  };
+}