1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
|
/*
Copyright (C) 2016 Michael Bohlender, <michael.bohlender@kdemail.net>
This program is free software; you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation; either version 2 of the License, or
(at your option) any later version.
This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
GNU General Public License for more details.
You should have received a copy of the GNU General Public License along
with this program; if not, write to the Free Software Foundation, Inc.,
51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
*/
import QtQuick 2.7
import QtQuick.Controls 2.0
import QtQuick.Controls 1.4 as Controls
import QtQuick.Layouts 1.1
import org.kube.framework 1.0 as Kube
FocusScope {
id: root
//Private properties
property variant parentFolder: null
property bool isDraft : false
property bool isImportant : false
property bool isTrash : false
property bool isUnread : false
property variant currentMail: null
onCurrentMailChanged: Kube.Fabric.postMessage(Kube.Messages.mailSelection, {"mail":currentMail})
Kube.Listener {
filter: Kube.Messages.folderSelection
onMessageReceived: {
parentFolder = message.folder
currentMail = null
}
}
Kube.Listener {
filter: Kube.Messages.search
onMessageReceived: {
mailListModel.filter = message.filterString
}
}
Shortcut {
sequence: StandardKey.Delete
enabled: !isTrash
onActivated: Kube.Fabric.postMessage(Kube.Messages.moveToTrash, {"mail":currentMail})
}
Kube.Label {
anchors.centerIn: parent
visible: listView.count === 0
//TODO depending on whether we synchronized already or not the label should change.
text: qsTr("Nothing here...")
}
Kube.ListView {
id: listView
anchors.fill: parent
clip: true
focus: true
ScrollBar.vertical: ScrollBar{
id: scrollbar
}
//BEGIN keyboard nav
onActiveFocusChanged: {
if (activeFocus && currentIndex < 0) {
currentIndex = 0
}
}
Keys.onDownPressed: {
incrementCurrentIndex()
}
Keys.onUpPressed: {
decrementCurrentIndex()
}
//END keyboard nav
onCurrentItemChanged: {
if (currentItem) {
root.currentMail = currentItem.currentData.mail;
root.isDraft = currentItem.currentData.draft;
root.isTrash = currentItem.currentData.trash;
root.isImportant = currentItem.currentData.important;
root.isUnread = currentItem.currentData.unread;
}
}
model: Kube.MailListModel {
id: mailListModel
parentFolder: root.parentFolder
}
delegate: Kube.ListDelegate {
id: delegateRoot
//Required for D&D
property var mail: model.mail
width: scrollbar.visible ? listView.width - scrollbar.width : listView.width
height: Kube.Units.gridUnit * 5
color: Kube.Colors.viewBackgroundColor
border.color: Kube.Colors.backgroundColor
border.width: 1
states: [
State {
name: "dnd"
when: mouseArea.drag.active
PropertyChanges {target: mouseArea; cursorShape: Qt.ClosedHandCursor}
PropertyChanges {target: delegateRoot; x: x; y: y}
PropertyChanges {target: delegateRoot; parent: root}
PropertyChanges {target: delegateRoot; opacity: 0.7}
PropertyChanges {target: delegateRoot; highlighted: true}
}
]
Drag.active: mouseArea.drag.active
Drag.hotSpot.x: mouseArea.mouseX
Drag.hotSpot.y: mouseArea.mouseY
Drag.source: delegateRoot
MouseArea {
id: mouseArea
anchors.fill: parent
drag.target: parent
onReleased: parent.Drag.drop()
onClicked: delegateRoot.clicked()
}
Item {
id: content
anchors {
fill: parent
margins: Kube.Units.smallSpacing
}
property color unreadColor: (model.unread && !delegateRoot.highlighted) ? Kube.Colors.highlightColor : delegateRoot.textColor
//TODO batch editing
// Kube.CheckBox {
// id: checkBox
//
// anchors.verticalCenter: parent.verticalCenter
// visible: (checked || delegateRoot.hovered) && !mouseArea.drag.active
// opacity: 0.9
// }
Column {
anchors {
verticalCenter: parent.verticalCenter
left: parent.left
leftMargin: Kube.Units.largeSpacing // + checkBox.width
}
Kube.Label{
id: subject
width: content.width - Kube.Units.gridUnit * 3
text: model.subject
color: content.unreadColor
maximumLineCount: 2
wrapMode: Text.WordWrap
elide: Text.ElideRight
}
Kube.Label {
id: sender
text: model.senderName
color: delegateRoot.textColor
font.italic: true
width: delegateRoot.width - Kube.Units.gridUnit * 3
elide: Text.ElideRight
}
}
Kube.Label {
id: date
anchors {
right: parent.right
bottom: parent.bottom
}
visible: !delegateRoot.hovered
text: Qt.formatDateTime(model.date, "dd MMM yyyy")
font.italic: true
color: Kube.Colors.disabledTextColor
font.pointSize: Kube.Units.tinyFontSize
}
Kube.Label {
id: threadCounter
anchors.right: parent.right
text: model.threadSize
color: content.unreadColor
visible: model.threadSize > 1
}
}
Row {
id: buttons
anchors {
right: parent.right
bottom: parent.bottom
margins: Kube.Units.smallSpacing
}
visible: delegateRoot.hovered && !mouseArea.drag.active
spacing: Kube.Units.smallSpacing
opacity: 0.7
Kube.IconButton {
id: readButton
iconName: Kube.Icons.markAsRead
visible: model.unread
onClicked: Kube.Fabric.postMessage(Kube.Messages.markAsRead, {"mail": model.mail})
activeFocusOnTab: false
}
Kube.IconButton {
id: unreadButton
iconName: Kube.Icons.markAsUnread
visible: !model.unread
onClicked: Kube.Fabric.postMessage(Kube.Messages.markAsUnread, {"mail": model.mail})
activeFocusOnTab: false
}
Kube.IconButton {
id: importantButton
iconName: Kube.Icons.markImportant
visible: !!model.mail
onClicked: Kube.Fabric.postMessage(Kube.Messages.toggleImportant, {"mail": model.mail, "important": model.important})
activeFocusOnTab: false
}
Kube.IconButton {
id: deleteButton
iconName: Kube.Icons.moveToTrash
visible: !!model.mail
onClicked: Kube.Fabric.postMessage(Kube.Messages.moveToTrash, {"mail": model.mail})
activeFocusOnTab: false
}
Kube.IconButton {
id: restoreButton
iconName: Kube.Icons.undo
visible: !!model.trash
onClicked: Kube.Fabric.postMessage(Kube.Messages.restoreFromTrash, {"mail": model.mail})
activeFocusOnTab: false
}
}
}
}
}
|
