1 files changed, 53 insertions, 0 deletions

diff --git a/icons/breeze/CMakeLists.txt b/icons/breeze/CMakeLists.txt
new file mode 100644
index 00000000..4fac9316
--- /dev/null
+++ b/icons/breeze/CMakeLists.txt
@@ -0,0 +1,53 @@
+include(KDEInstallDirs)
+
+set(BINARY_ICONS_RESOURCE TRUE)
+if(BINARY_ICONS_RESOURCE)
+    find_package(Qt5 NO_MODULE REQUIRED Core)
+    add_executable(qrcAlias qrcAlias.cpp)
+    target_link_libraries(qrcAlias PUBLIC Qt5::Core)
+
+    function(generate_binary_resource target outfile)
+        set(RESOURCES_WORKING_DIR ${CMAKE_CURRENT_BINARY_DIR}/res)
+        set(RESOURCE_FILE ${RESOURCES_WORKING_DIR}/kube-${target}.qrc)
+        set(BINARY_RESOURCE_FILE ${CMAKE_CURRENT_BINARY_DIR}/kube-${target}.rcc)
+
+        get_target_property(QT_RCC_EXECUTABLE Qt5::rcc LOCATION)
+
+        file(REMOVE_RECURSE ${RESOURCES_WORKING_DIR})
+        file(MAKE_DIRECTORY ${RESOURCES_WORKING_DIR})
+        file(COPY ${CMAKE_CURRENT_SOURCE_DIR}/${target}/ DESTINATION ${RESOURCES_WORKING_DIR})
+        file(REMOVE
+            ${RESOURCE_FILE}
+            ${RESOURCE_FILE}.depends
+            ${RESOURCES_WORKING_DIR}/.gitignore
+            ${RESOURCES_WORKING_DIR}/CMakeLists.txt
+        )
+
+        add_custom_command(OUTPUT ${RESOURCE_FILE}
+            COMMAND ${QT_RCC_EXECUTABLE} --project -o ${CMAKE_CURRENT_BINARY_DIR}/tmp.qrc
+            COMMAND $<TARGET_FILE:qrcAlias> -i ${CMAKE_CURRENT_BINARY_DIR}/tmp.qrc -o ${RESOURCE_FILE}
+            WORKING_DIRECTORY ${RESOURCES_WORKING_DIR}
+        )
+        add_custom_command(OUTPUT ${BINARY_RESOURCE_FILE}
+            COMMAND ${QT_RCC_EXECUTABLE} --binary
+                        -o ${BINARY_RESOURCE_FILE}
+                        ${RESOURCE_FILE}
+            DEPENDS ${RESOURCE_FILE}
+            WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
+        )
+
+        add_custom_target(kube-${target}-rcc ALL DEPENDS ${BINARY_RESOURCE_FILE})
+
+        set(${outfile} ${BINARY_RESOURCE_FILE} PARENT_SCOPE)
+    endfunction()
+
+    generate_binary_resource(icons binary_resource)
+    install(FILES ${binary_resource} DESTINATION ${KDE_INSTALL_DATADIR}/kube)
+else()
+    install(DIRECTORY
+        icons/places
+        icons/actions
+        icons/mimetypes
+        DESTINATION ${KDE_INSTALL_FULL_ICONDIR}/kube)
+    install(FILES icons/index.theme DESTINATION ${KDE_INSTALL_FULL_ICONDIR}/kube)
+endif()