One copy of the gpg helpers is enough.

2 files changed, 106 insertions, 0 deletions

diff --git a/cmake/modules/add_gpg_crypto_test.cmake b/cmake/modules/add_gpg_crypto_test.cmake
new file mode 100644
index 00000000..c3df76c9
--- /dev/null
+++ b/cmake/modules/add_gpg_crypto_test.cmake
@@ -0,0 +1,61 @@
+# Copyright (c) 2013 Sandro Knauß <mail@sandroknauss.de>
+#
+# Redistribution and use is allowed according to the terms of the BSD license.
+# For details see the accompanying COPYING-CMAKE-SCRIPTS file.
+
+set( MIMETREEPARSERRELPATH framework/src/domain/mime/mimetreeparser)
+set( GNUPGHOME ${CMAKE_BINARY_DIR}/${MIMETREEPARSERRELPATH}/tests/gnupg_home )
+add_definitions( -DGNUPGHOME="${GNUPGHOME}" )
+
+macro (ADD_GPG_CRYPTO_TEST _target _testname)
+   if (UNIX)
+      if (APPLE)
+         set(_library_path_variable "DYLD_LIBRARY_PATH")
+      elseif (CYGWIN)
+         set(_library_path_variable "PATH")
+      else (APPLE)
+         set(_library_path_variable "LD_LIBRARY_PATH")
+      endif (APPLE)
+
+      if (APPLE)
+         # DYLD_LIBRARY_PATH does not work like LD_LIBRARY_PATH
+         # OSX already has the RPATH in libraries and executables, putting runtime directories in
+         # DYLD_LIBRARY_PATH actually breaks things
+         set(_ld_library_path "${LIBRARY_OUTPUT_PATH}/${CMAKE_CFG_INTDIR}/")
+      else (APPLE)
+         set(_ld_library_path "${LIBRARY_OUTPUT_PATH}/${CMAKE_CFG_INTDIR}/:${LIB_INSTALL_DIR}:${QT_LIBRARY_DIR}")
+      endif (APPLE)
+      set(_executable "$<TARGET_FILE:${_target}>")
+
+      # use add_custom_target() to have the sh-wrapper generated during build time instead of cmake time
+      add_custom_command(TARGET ${_target} POST_BUILD
+        COMMAND ${CMAKE_COMMAND}
+        -D_filename=${_executable}.shell -D_library_path_variable=${_library_path_variable}
+        -D_ld_library_path="${_ld_library_path}" -D_executable=$<TARGET_FILE:${_target}>
+        -D_gnupghome="${GNUPGHOME}"
+        -P ${CMAKE_SOURCE_DIR}/cmake/modules/generate_crypto_test_wrapper.cmake
+      )
+
+      set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${_executable}.shell" )
+      add_test(NAME ${_testname} COMMAND ${_executable}.shell)
+
+   else (UNIX)
+      # under windows, set the property WRAPPER_SCRIPT just to the name of the executable
+      # maybe later this will change to a generated batch file (for setting the PATH so that the Qt libs are found)
+      set(_ld_library_path "${LIBRARY_OUTPUT_PATH}/${CMAKE_CFG_INTDIR}\;${LIB_INSTALL_DIR}\;${QT_LIBRARY_DIR}")
+      set(_executable "$<TARGET_FILE:${_target}>")
+
+      # use add_custom_target() to have the batch-file-wrapper generated during build time instead of cmake time
+      add_custom_command(TARGET ${_target} POST_BUILD
+         COMMAND ${CMAKE_COMMAND}
+         -D_filename="${_executable}.bat"
+         -D_ld_library_path="${_ld_library_path}" -D_executable="${_executable}"
+         -D_gnupghome="${GNUPGHOME}"
+         -P ${CMAKE_SOURCE_DIR}/cmake/modules/generate_crypto_test_wrapper.cmake
+         )
+
+      add_test(NAME ${_testname} COMMAND ${_executable}.bat)
+
+   endif (UNIX)
+endmacro (ADD_GPG_CRYPTO_TEST)
+
diff --git a/cmake/modules/generate_crypto_test_wrapper.cmake b/cmake/modules/generate_crypto_test_wrapper.cmake
new file mode 100644
index 00000000..e1412f37
--- /dev/null
+++ b/cmake/modules/generate_crypto_test_wrapper.cmake
@@ -0,0 +1,45 @@
+# Copyright (c) 2006, Alexander Neundorf, <neundorf@kde.org>
+# Copyright (c) 2013, Sandro Knauß <mail@sandroknauss.de>
+#
+# Redistribution and use is allowed according to the terms of the BSD license.
+# For details see the accompanying COPYING-CMAKE-SCRIPTS file.
+
+
+if (UNIX)
+
+file(WRITE "${_filename}"
+"#!/bin/sh
+# created by cmake, don't edit, changes will be lost
+
+# don't mess with a gpg-agent already running on the system
+unset GPG_AGENT_INFO
+
+${_library_path_variable}=${_ld_library_path}\${${_library_path_variable}:+:\$${_library_path_variable}} GNUPGHOME=${_gnupghome} gpg-agent --daemon \"${_executable}\" \"$@\"
+_result=$?
+_pid=`echo GETINFO pid | GNUPGHOME=${_gnupghome} gpg-connect-agent | grep 'D' | cut -d' ' -f2`
+if [ ! -z \"\$_pid\" ]; then
+    echo \"Waiting for gpg-agent to terminate (PID: $_pid)...\"
+    while kill -0 \"\$_pid\"; do
+        sleep 1
+    done
+fi
+exit \$_result
+")
+
+# make it executable
+# since this is only executed on UNIX, it is safe to call chmod
+exec_program(chmod ARGS ug+x \"${_filename}\" OUTPUT_VARIABLE _dummy )
+
+else (UNIX)
+
+file(TO_NATIVE_PATH "${_ld_library_path}" win_path)
+file(TO_NATIVE_PATH "${_gnupghome}" win_gnupghome)
+
+file(WRITE "${_filename}"
+"
+set PATH=${win_path};$ENV{PATH}
+set GNUPGHOME=${win_gnupghome};$ENV{GNUPGHOME}
+gpg-agent --daemon \"${_executable}\" %*
+")
+
+endif (UNIX)